Global assumptions

$Assumptions=x∈Reals && 0<x<=1&&β∈Reals&&0<β<1&&x+β<1;

Define plus ditributions for [1/(1-x)] and [ln(1-x)/(1-x)]

PlusDist[x_,β_] =HeavisideTheta[1-β-x]/(1-x)+DiracDelta[1-β-x]Log[β];

PlusDist1[x_,β_] = 2(HeavisideTheta[1-β-x]Log[1-x]/(1-x)+DiracDelta[1-β-x]Log[β]^2/2)-3PlusDist[x,β]/2;

PlusDistEps[x_,β_] = x^(-β)/(1-x)^(1-β)-DiracDelta[1-x]/β;

Next-to-leading-order FL coefficient functions

CL1q[x_]=REG 4 CF x ;

CL1g[x_]=REG 16 TR x (1-x);

Next-to-leading-order F2 coefficient functions

C21q[x_,β_]=CF(SING PlusDist1[x,β]+REG(-(1+x)(Log[1-x]-Log[x])-2Log[x]/(1-x)+3+2x)+LOC(-(2Zeta[2]+9/2)DiracDelta[1-x]));

C21g[x_]= REG 4TR(((1-x)^2+x^2) (Log[1-x]-Log[x])-8x^2+8x-1);

Leading-oder splitting functions

Pqq[x_,β_]=2CF(SING 2PlusDist[x,β]-REG(1+x)+LOC 3DiracDelta[1-x]/2);

Pqg[x_] = REG 4 NF TR (x^2+(1-x)^2);

Pgq[x_]=REG 2CF(1+(1-x)^2)/x;

Pgg[x_,β_]= 4 CA (SING PlusDist[x,β]+REG(-2+x-x^2+1/x))+LOC(11CA - 4 NF TR)DiracDelta[1-x]/3;

PqqEps[x_,β_]=2CF(SING 2PlusDistEps[x,β]-REG(1+x)+LOC 3DiracDelta[1-x]/2);

PggEps[x_,β_]= 4 CA (SING PlusDistEps[x,β]+REG(-2+x-x^2+1/x))+LOC(11CA - 4 NF TR)DiracDelta[1-x]/3;

Evaluate convolutions between splitting functions:

P0P0g[x_]=Collect[Limit[Integrate[(Pqq[y,β]Pqg[x/y]+Pgg[y,β]Pqg[x/y])/y,{y,x,1}]/.{HeavisideTheta[0]->1,REG->1,SING->1,LOC->1},β->0]/.{Log[-(x/(-1+x))]->Log[x]-Log[1-x]},{CF,TR NF,CA,Log[x],Log[1-x]},Simplify]

P0P0ps[x_]=Collect[Integrate[Pqg[y]Pgq[x/y]/y,{y,x,1}]/.{HeavisideTheta[0]->1,REG->1,SING->1,LOC->1}/.{Log[-(x/(-1+x))]->Log[x]-Log[1-x]},{CF,TR NF,CA,Log[x],Log[1-x]},Simplify]

Evaluate convolutions for FL

CL1P0g[x_]=Collect[Limit[Integrate[(CL1q[x/y]Pqg[y]/NF+CL1g[x/y]Pgg[y,β])/y,{y,x,1}]/.{HeavisideTheta[0]->1,REG->1,SING->1,LOC->1},β->0]/.{Log[(1/(1-x))]->-Log[1-x],Log[-(x/(-1+x))]->Log[x]-Log[1-x]},{CF,TR NF,CA,Log[x],Log[1-x]},Simplify]

CL1P0ps[x_] =Collect[Integrate[CL1g[x/y]Pgq[y]/y,{y,x,1}]/.{HeavisideTheta[0]->1,REG->1,SING->1,LOC->1}/.{Log[(1/(1-x))]->-Log[1-x],Log[-(x/(-1+x))]->Log[x]-Log[1-x]},{CF,TR,CA,Log[x],Log[1-x]},Simplify]

CL1P0pm[x_] = NF Collect[Limit[Integrate[CL1q[x/y]Pqq[y,β]/y,{y,x,1}]/.{HeavisideTheta[0]->1,REG->1,SING->1,LOC->1},β->0]/.{Log[(1/(1-x))]->-Log[1-x],Log[-(x/(-1+x))]->Log[x]-Log[1-x]},{CF,TR,CA,Log[x],Log[1-x]},Simplify]