{+ file: rename_segid.inp +}
{+ directory: general +}
{+ description: Rename segid(s) +}
{+ comment: 
           Reads in a coordinate and structure file, renames the
           selected segid information and writes out a new 
           coordinate and structure file +}
{+ authors: Axel T. Brunger, and Paul D. Adams +}
{+ copyright: Yale University +}

{- Guidelines for using this file:
   - all strings must be quoted by double-quotes
   - logical variables (true/false) are not quoted
   - do not remove any evaluate statements from the file -}

{- begin block parameter definition -} define(

{============================ coordinates ============================}

{* coordinate file *}
{===>} coordinate_infile="fab2hfl.pdb";

{==================== molecular information ==========================}

{* topology files *}
{===>} topology_infile_1="CNS_TOPPAR:protein.top";
{===>} topology_infile_2="CNS_TOPPAR:dna-rna.top";
{===>} topology_infile_3="CNS_TOPPAR:water.top";
{===>} topology_infile_4="CNS_TOPPAR:ion.top";
{===>} topology_infile_5="CNS_TOPPAR:carbohydrate.top";
{===>} topology_infile_6="";
{===>} topology_infile_7="";
{===>} topology_infile_8="";

{* linkage files for linear, continuous polymers (protein, DNA, RNA) *}
{===>} link_infile_1="CNS_TOPPAR:protein.link";
{===>} link_infile_2="CNS_TOPPAR:dna-rna-pho.link";
{===>} link_infile_3="";

{* parameter files *}
{===>} parameter_infile_1="CNS_TOPPAR:protein_rep.param";
{===>} parameter_infile_2="CNS_TOPPAR:dna-rna_rep.param";
{===>} parameter_infile_3="CNS_TOPPAR:water_rep.param";
{===>} parameter_infile_4="CNS_TOPPAR:ion.param";
{===>} parameter_infile_5="CNS_TOPPAR:carbohydrate.param";
{===>} parameter_infile_6="";
{===>} parameter_infile_7="";
{===>} parameter_infile_8="";

{* molecular topology file: optional (leave blank for auto generation) *}
{* 
   Auto generation of the molecular topology from the coordinates should only 
   be used if:
   (1) Each distinct protein, DNA, or RNA chain must have a separate segid 
       (or chainid if the chainid is non-blank). 
   (2) Each contiguous protein, RNA, or RNA chain must not be disrupted by 
       other types of residues or ligands.  Rather, these other residues 
       should be listed after protein, RNA/DNA chains. 
   (3) Disulphides are automatically detected based on distances between the sulfur atoms
      (must be less than 3 A apart).
   (4) Broken protein/RNA/DNA chains without terminii must be more than 2.5 A apart to be recognized as such.
   (5) N-linked glycan links are automatically recognized if the bonded atoms are less than 2.5 A apart.
   (6) Automatic generation cannot be used with alternate conformations. 
   For ligands, the user must make suitable topology and parameter files.
   For non-standard covalent linkages, the custom patch file should be used.
   Alternatively, the generate.inp or generate_easy.inp task files
   can be used to generated the mtf prior to running this task file.
    *}
{===>} structure_infile="fab2hfl.mtf";

{* for auto generation: extra linkages and modifications by custom patches *}
{===>} patch_infile="";


{========================== renaming segids ==========================}

{+ table: rows=10 numbered
          cols=2 "old segid" "new segid" +}

{===>} segid_old_1="L";
{===>} segid_new_1="A";

{===>} segid_old_2="H";
{===>} segid_new_2="B";

{===>} segid_old_3="";
{===>} segid_new_3="";

{===>} segid_old_4="";
{===>} segid_new_4="";

{===>} segid_old_5="";
{===>} segid_new_5="";

{===>} segid_old_6="";
{===>} segid_new_6="";

{===>} segid_old_7="";
{===>} segid_new_7="";

{===>} segid_old_8="";
{===>} segid_new_8="";

{===>} segid_old_9="";
{===>} segid_new_9="";

{===>} segid_old_10="";
{===>} segid_new_10="";

{=========================== output files ============================}

{* output molecular structure file *}
{===>} structure_outfile="rename_segid.mtf";

{* output coordinate file *}
{===>} coordinate_outfile="rename_segid.pdb";

{===========================================================================}
{        things below this line do not normally need to be changed          }
{===========================================================================}

 ) {- end block parameter definition -}

 checkversion 1.3

 evaluate ($log_level=quiet)

   if ( $log_level = verbose ) then
   set message=normal echo=on end
 else
   set message=off echo=off end
 end if

 if ( &BLANK%structure_infile = true ) then
 
    {- read topology files -}
    topology
     evaluate ($counter=1)
     evaluate ($done=false)
     while ( $done = false ) loop read
      if ( &exist_topology_infile_$counter = true ) then
         if ( &BLANK%topology_infile_$counter = false ) then
            @@&topology_infile_$counter
         end if
      else
        evaluate ($done=true)
      end if
      evaluate ($counter=$counter+1)
     end loop read
    end
    
    @CNS_XTALMODULE:mtfautogenerate (
                                  coordinate_infile=&coordinate_infile;
                                  convert=true;
                                  separate=true;
                                  atom_delete=(not known);
                                  hydrogen_flag=true;
                                  break_cutoff=2.5;
                                  disulphide_dist=3.0;
                                  carbo_dist=2.5;
                                  patch_infile=&patch_infile;
                                  O5_becomes="O";
                                 )

 else

   structure @&structure_infile end
   coordinates @&coordinate_infile

 end if

 {- read parameter files -}
 parameter
  evaluate ($counter=1)
  evaluate ($done=false)
  while ( $done = false ) loop read
   if ( &exist_parameter_infile_$counter = true ) then
      if ( &BLANK%parameter_infile_$counter = false ) then
         @@&parameter_infile_$counter
      end if
   else
     evaluate ($done=true)
   end if
   evaluate ($counter=$counter+1)
  end loop read
 end

 set message=normal echo=on end

 evaluate ($segnum=1)
 evaluate ($done=false)

 while ( $done = false ) loop safe

   if ( &exist_segid_old_$segnum = true ) then
     if ( &segid_old_$segnum # &segid_new_$segnum ) then
       evaluate ($segtmp="T^" + encode($segnum))
       do (segid=$segtmp) (segid=&segid_old_$segnum)
     end if
   else
     evaluate ($done=true)
   end if

   evaluate ($segnum=$segnum+1)

 end loop safe

 evaluate ($segnum=1)
 evaluate ($done=false)

 while ( $done = false ) loop rename

   if ( &exist_segid_old_$segnum = true ) then
     if ( &segid_old_$segnum # &segid_new_$segnum ) then
       evaluate ($segold="T^" + encode($segnum))
       evaluate ($segid=capitalize(&segid_new_$segnum))
       do (segid=$segid) (segid=$segold)
     end if
   else
     evaluate ($done=true)
   end if

   evaluate ($segnum=$segnum+1)

 end loop rename

 write structure output=&structure_outfile end

 write coordinate output=&coordinate_outfile format=PDBO  end

 stop