{+ file: cns_to_sdb.inp +}
{+ directory: xtal_phase +}
{+ description: Convert CNS coordinate and molecular structure information
                into a CNS heavy atom site database file +}
{+ comment: 
           This file should be used to convert a preexisting CNS
           coordinate and molecular topology file to a CNS heavy
           atom site database file. +}
{+ authors: Axel T. Brunger, and Paul D. Adams +}
{+ copyright: Yale University +}

{- Guidelines for using this file:
   - all strings must be quoted by double-quotes
   - logical variables (true/false) are not quoted
   - do not remove any evaluate statements from the file -}

{- begin block parameter definition -} define(

{============================ space group ============================}

{* space group *}
{* use International Table conventions with subscripts substituted
   by parenthesis *}
{===>} sg="P2(1)2(1)2(1)";

{======================= molecular structure =========================}

{* heavy atom structure file *}
{===>} structure_infile_1="mbp_sites.mtf";

{* heavy atom coordinate file *}
{===>} coordinate_infile_1="mbp_sites.pdb";

{============================ output file ============================}

{* output CNS heavy atom site database file *}
{===>} sitedatabase_outfile="cns_to_sdb.sdb";

{===========================================================================}
{        things below this line do not normally need to be changed          }
{===========================================================================}

 ) {- end block parameter definition -}

 checkversion 1.3

 evaluate ($log_level=quiet)

 evaluate ($struct=1)
 evaluate ($done=false)

 while ( $done = false ) loop struct

   if ( &BLANK%structure_infile_$struct = false ) then
     structure @@&structure_infile_$struct end
     coordinates @@&coordinate_infile_$struct
   else
     evaluate ($done=true)
   end if

   evaluate ($struct=$struct+1)

 end loop struct

 identity (store3) (all)
 identity (store4) (none)

 @CNS_XTALMODULE:coord_to_sdb (sitedb=$allsites;
                               use_array=store3;
                               fix_array=store4;
                               selection=(all);)

 buffer comment
   reset
   display            This site database converted from CNS coordinates and
   display            molecular topology file.
 end

 @CNS_XTALMODULE:write_cns_header (output=&sitedatabase_outfile;
                                   description="CNS heavy atom site database";
                                   buffer=comment;)

 @CNS_XTALMODULE:write_sdb (sitedb=$allsites;
                            sg=&sg;
                            output=&sitedatabase_outfile;)

 stop