#!/bin/csh

if (-e /u/config/`hostname`.config) then
   source /u/config/`hostname`.config
endif

set   history = 500 

alias h      'history'
alias rm     'rm -i'
alias u      'chmod a+x *.com *.tcl'
alias cd     'cd \!*; set prompt = "$cwd% "'
alias dirs   'ls -l | egrep -e ^d'
alias links  'ls -l | egrep -e ^l'
alias tman   'man -M /usr/local/man'
alias psview 'ghostview -landscape'

if ($OSTYPE == bsd) then
   alias pis  'ps aux | sort | more'
   alias rsh  /usr/ucb/rsh
else
   alias pis  'ps -ef | sort | more'
   alias rsh  /usr/bsd/rsh
endif

if ($?prompt) then
   set prompt = `hostname | sed -e 's/\..*//'`'% '
endif

setenv TITLE   `hostname | sed -e 's/\..*//'`' '
setenv EDITOR   /usr/ucb/vi

if (!($?PATHSET)) then
   set path = (. $path \
                 /usr/lang /usr/bin/X11 /usr/local/bin/X11 /usr/openwin/bin  \
                 /usr/local/bin /usr/bsd /usr/ucb /usr/sbin /usr/ccs/bin)

   setenv PATHSET TRUE 
endif

if (-e /u/delaglio/com/nmrInit.sol.com) then
   source /u/delaglio/com/nmrInit.sol.com
endif

if (-e /u/delaglio/dynamo/com/dynInit.com) then
   source /u/delaglio/dynamo/com/dynInit.com
endif

if (!($?PATHFIXED)) then
   set path = (`uniqenv.com "$path" " "`)
   setenv PATHFIXED TRUE
endif

