# Copyright (c) 2002-08 Peter Guntert. All rights reserved.
## 7MACROS: deposit - CYANA macro
##
## Parameters: pdb=<filename>.pdb             (default: <blank>)
##             bmrb=<filename>.bmrb           (default: <blank>)
##

var i n dummy closest r rmin

syntax $macro:pdb=@f.pdb= bmrb=@f.bmrb=


# ------ prepare file for coordinate deposition to PDB ------

if ('$pdb'.ne.' ') then
  # Make conformer closest to the mean the first conformer
  atom select "N CA C $rmsdrange"
  structure mean
  write cor tmpmean.cor
  write_all tmp cor
  n=nstruct
  rmin=1.0E20
  do i 1 n
    read cor tmpmean.cor
    read cor tmp$i(I3.3).cor append
    dummy=rmsdmean; r=rmsdpair
    if (r.lt.rmin) closest=i
#    print "i=$i r=$r rmin=$rmin closest=$closest"
    rmin=min(r,rmin)
  end do
  remove tmpmean.cor
  read cor tmp$closest(I3.3).cor
  do i 1 n
    if (i.ne.closest) read cor tmp$i(I3.3).cor append
    remove tmp$i(I3.3).cor
  end do
  #i=indexr('$pdb','.')
  #write pdb $pdb(1:i-1)0 all

  # Write file for PDB
  #translate pdb
  atom select "N CA C $rmsdrange"
  write pdb $pdb bfactor=0.0 chains=ABC details all
  #translate off
end if


# ------ prepare file for chemical shift deposition to BMRB ------

if ('$bmrb'.ne.' ') then
  translate bmrb
  atom select "ASSIGNED"
  atom set "H* Q*" tolerance=$tolerance(1)
  atom set "N* C*" tolerance=$tolerance(3)
  write bmrb $bmrb details
  translate off
end if