# Copyright (c) 2002-08 Peter Guntert. All rights reserved.
## 7MACROS: prolinebond - CYANA macro
##
## Parameters: range=<integer range>          (default: <all residues>)
##
## Creates upper and lower limit restraints to "close" the bonds between
## CG and CD in flexible proline rings in the given residue range.

var info echo i res n aco

syntax $macro:range=@ii=$rnum(1)..$rnum(nr)

echo:=off
info:=none
aco:=d$getpid.aco
print "\# Angle restraints for flexible proline rings" >$aco
n=0
do i 1 nr
  res=rnum(i)
  if (res.ge.range(1) .and. res.le.range(2) .and. rnam(i).eq.'PROO') then
    n=n+1
    distance make "CD $res" "CG  $res" lol=1.49 upl=1.51 weight=10.0
    distance make "CD $res" "CB  $res" lol=2.39 upl=2.40
    distance make "CD $res" "HG? $res" lol=2.12 upl=2.13
    distance make "CG $res" "N   $res" lol=2.33 upl=2.34
    distance make "CG $res" "HD? $res" lol=2.12 upl=2.13
    print "$res $rnam(i) PHI  -80.0 -40.0" >>
    print "$res $rnam(i) CHI1 -30.0  30.0" >>
    print "$res $rnam(i) CHI2  80.0 160.0" >>
    print "$res $rnam(i) CHI3  50.0  80.0" >>
  end if
end do
print >>.
read aco $aco append
remove $aco
print "    Restraints for $n proline rings added."