#!/bin/csh -f
#TEST-PROGRAM sander
#TEST-DESCRIP TO_BE_DEtermined
#TEST-PURPOSE regression, basic
#TEST-STATE   undocumented

if( ! $?MMTSBDIR ) then
    echo " ERROR:  MMTSBDIR is not set !"
    echo " Set MMTSBDIR to the root of your MMTSB installation."
    echo " And include MMTSBDIR/perl and MMTSBDIR/bin in your path."
    goto error
endif

if( ! $?AMBERHOME ) then
    setenv AMBERHOME "`pwd`/.."
    echo " Warning: AMBERHOME is not set."
    echo "Caution: Setting AMBERHOME to $AMBERHOME !"
endif

if( ! $?SANDEREXEC ) then
    echo " Warning: SANDEREXEC is not set."
    if( ! $?TESTsander ) then
        set TESTsander = "../../bin/sander"
        setenv SANDEREXEC "$AMBERHOME/bin/sander"
    else
        setenv SANDEREXEC "$TESTsander"
    endif
    echo "Caution: Setting SANDEREXEC to $TESTsander !"
endif

if( ! $?DO_PARALLEL ) then
    setenv DO_PARALLEL " "
endif

# Temperature replica-exchange of RNaseA.
# This is more an example than a test case.
# The aarexAmber.pl command line is explained.
#-temp 4:300:320
# 4 temperature windows, starting at 300 K, ending at 320 K;
# the intermediate temperatures, which are determined by MMTSB,
# will be exponentially spaced.
#-par partop=prmtop.prt.rnase.GB,saverestart,archive
# parameters for the simulation:  prmtop.prt.rnase.GB is the
# Amber prmtop file; save the MMTSB restart file; archive the
# calculation by saving the trajectory files.  See the usage
# statement of aarexAmber.pl and the online documentation at
# http://mmtsb.scripps.edu/doc for the available options.
# (See also $MMTSBDIR/perl/ReXServer.pm as a last resort.)
#-mdpar gb=obc,nocut,dynsteps=4,lambda=0.5
# MD parameters for the simulation:  Generalized Born method obc,
# ie, igb=2; no cutoff, ie, cut=9999.0; 4 Amber MD steps between
# each attempted temperature exchange, ie, mmtsb_iterations=4;
# the thermodynamic integration lambda value, ie, clambda=0.5. 
# See the usage statement of aarexAmber.pl and the online
# documentation at
# http://mmtsb.scripps.edu/doc for the available options.
# (See also $MMTSBDIR/perl/Amber.pm as a last resort.)
#-n 5
# the number of replica exchange steps; the total number of
# MD steps is mmtsb_iterations times this value, 4 * 5 = 20.
#-log rex.log
# the MMTSB log file.
#-amberlog amber.log
# the Amber output files.
#-dir rnasea
# the working directory is rnasea
#eq_rnase_GB_3p_l2_1.x.pdb.1
# the initial structure for the simulation in PDB format.

set dir = rnasea
set output = mdout.rnasea

aarexAmber.pl -temp 4:300:320 -par partop=prmtop.prt.rnase.GB,saverestart,archive -mdpar gb=obc,nocut,dynsteps=4,lambda=0.5 -n 5 -log rex.log -amberlog $output -dir $dir eq_rnase_GB_3p_l2_1.x.pdb.1

../dacdif $dir/save.rexserver.cond $dir/rexserver.cond 
# The output files should be different because of the different
# Amber random seeds, ig, created by MMTSB.
#../dacdif $dir/aa1/$output.save $dir/aa1/$output
#../dacdif $dir/aa2/$output.save $dir/aa2/$output
#../dacdif $dir/aa3/$output.save $dir/aa3/$output
#../dacdif $dir/aa4/$output.save $dir/aa4/$output
#../dacdif $dir/aa1/final.pdb.save $dir/aa1/final.pdb

/bin/rm -f fort.7 $dir/rex*
exit(0)

error:
echo "  ${0}:  Program error"
exit(1)