rtf @TOPPAR:protein.top end
parameter @TOPPAR:protein.par end





segment
   SETUP=TRUE
   chain
@TOPPAR:toph11.pep
sequence
MET THR TYR LYS LEU ILE LEU ASN GLY LYS THR LEU LYS GLY GLU THR THR THR
GLU ALA VAL ASP ALA ALA THR ALA GLU LYS VAL PHE LYS GLN TYR ALA ASN ASP
ASN GLY VAL ASP GLY GLU TRP THR TYR ASP ASP ALA THR LYS THR PHE THR VAL
THR GLU end
end
end





write psf output=protG.psf end

set seed 787493093 end



vector ident (x) (all)
vector do (x=x/10.0) (all)
vector do (y=random(0.5) ) (all)
vector do (z=random(0.5) ) (all)
{* This assigns X, Y, and Z coordinates to each atom. The Y and Z coordinates *}
{* are random (but small enough (within a range of -0.5 to 0.5) to allow      *}
{* bonded atoms to form their bonds)                                          *}
{* and the X coordinate is the atom number divided by 10. This will result in *}
{* an extended configuration along the X axis.                                *}

vector do (fbeta=50) (all)      {* coupling to heat bath *}
vector do (mass=100) (all)
                                {* all atom masses are set the same so that *}
                                {* motion of each atom is equally likely in *}
                                {* the dynamics. Note that the dynamics is  *}
                                {* not a realistic model of the motion of   *}
                                {* the system; it is a method of minimizing *}
                                {* a highly complicated function.           *}
parameter
 nbonds
  {* because we are starting from random coordinates for ALL atoms, the van   *}
  {* der Waals repulsion term has to be very strong to keep atoms from passing*}
  {* through each other (rcon=20). The negative nbxmod parameter means that   *}
  {* even atoms that have been explicitly told not to interact with each other*}
  {* (in the topology when the system was generated) are subjected to van der *}
  {* Waals interactions. The 2 means that interactions between bonded atoms   *}
  {* are not used.                                                            *}
  cutnb=5.5 rcon=20. nbxmod=-2 repel=0.9 wmin=0.1 tolerance=1.
  rexp=2 irexp=2 inhibit=0.25
 end
end

flags exclude * include bond angle vdw end
minimize powell nstep=50 nprint=10 end
flags include impr end
minimize powell nstep=50 nprint=10 end
{* First minimization, with van der Waals. *}

dynamics verlet
  nstep=50 timestep=0.001 iasvel=maxwell firsttemp=300.
  tcoupling=true tbath=300.0 nprint=50 iprfrq=0
end
{* Dynamics without a lot of kinetic energy. By keeping the kinetic energy    *}
{* low, the system is less likely to "explode", have the atoms separate in an *}
{* uncontrolled manner. The potential energies are quite high at this step    *}
{* because the bonds and angles are violated by the random starting structure *}
{* and several 100's of steps of minimization and dynamics are needed to allow*}
{* the structure to find a correct covalent geometry.                         *}

parameter
  nbonds
   rcon=2.0 nbxmod=-3 repel=0.75  
  {* the strength of the van der Waals interaction is reduced (rcon=2.0). The *}
  {* negative nbxmod parameter means that   *}
  {* even atoms that have been explicitly told not to interact with each other*}
  {* (in the topology when the system was generated) are subjected to van der *}
  {* Waals interactions. The 3 means that interactions between atoms separated*}
  {* by two bonds (A-B-C) are not used.                                       *}
 end
end

minimize powell nstep=100 nprint=25 end

dynamics verlet
 nstep=500 timestep=0.005 iasvel=maxwell firsttemp=300.0
 tcoupling=true tbath=300.0 nprint=100 iprfrq=0
end
{* This round of dynamics is highly effective in bringing down the bond and   *}
{* angle energies. This is also conducted with low kinetic energy.            *}

flags exclude vdw elec end
{* hbuild works better if non-bonded interactions are turned off.             *}

vector do (mass=1.0) (name h*)    {* The mass of the hydrogens must be set to *}
{* a value less than 3.5, in order for the hbuild statement to recognize them.*}

hbuild select=(name h*) phistep=360 end
{* The hydrogen atoms are built into the most likely positions by a process   *}
{* that tries various positions. It attempts to make hydrogen bonds if an     *}
{* acceptor is in position.                                                   *}

flags include vdw elec end

minimize powell nstep=200 nprint=50 end

write coords output=template_protG.pdb end

stop