remarks LANGTEST1
remarks  This is a test file which builds a butane
remarks  molecule from 4 extended atoms and then runs
remarks  a series of Langevin dynamics tests. The initial
remarks  positions of the molecule are with the dihedral
remarks  angle at 180 degrees.  Both bonds and bond angles
remarks  are SHAKen.

rtf
remarks rtf for butane

MASS CH2E  14.02700
MASS CH3E  15.03500

RESIdue BUT
 ATOM C1  TYPE CH3E CHARGE 0.0  END
 ATOM C2  TYPE CH2E CHARGE 0.0  END
 ATOM C3  TYPE CH2E CHARGE 0.0  END
 ATOM C4  TYPE CH3E CHARGE 0.0  END

 BOND C1 C2
 BOND C2 C3
 BOND C3 C4

 ANGLE  C1 C2 C3
 ANGLE  C2 C3 C4

 DIHEDRAL C1 C2 C3 C4

 IC C1 C2 C3 C4   0.0 0.0 180.0 0.0 0.0
 IC  X C1 C2 C3   0.0 0.0 180.0 0.0 0.0

END {BUT}

END !RTF

parameter @TOPPAR:param11.pro end

SEGMENT
  SETUPIC=T
  NAME=BUTE
  MOLECULE
    NAME=BUT NUMBER=1
  END
END

IC 
  FILL 
    REFERENCE PARAMETERS 
  END
  WRITE END
  BUILD
    SEED ( ATOM BUTE 1 C1 ) ( ATOM BUTE 1 C2 ) ( ATOM BUTE 1 C3 ) 
  END
END

WRITE COOR END

VECTOR DO ( FBETA = 6.657235 ) {1/ps} ( SEGID BUTE AND RESID 1 )
VECTOR SHOW ELEMENT ( FBETA ) ( ALL )

! We SHAKE bonds and bond angles to simplify things
SHAKE
  TOL=1.0E-5  
  BONDS (all) (all)
  ANGLES (all) (all) (all)
END

parameter 
   NBONDS NBXMOD 4 END
end                      

energy end

WRITE COOR  END

! Run 2.5 ps of Langevin dynamics with initial temperature
! set to 291.0 K.  Save the trajectory to analyze the rms
! fluctuations.                 
set seed=71403814. end
DYNA LANG 
      TIMESTEP=0.001 NSTEP=2500 
      FIRSTT=290.0 FINALT=291.4 TWINDL=100.0 TWINDH=100.0
      ILBFRQ=2500 IEQFRQ=0 IPRFRQ=0  NPRINT=20 iasvel=maxwell 
      TBATH=291.0
      trajectory=langtest1.dat NSAVC=5
END

WRITE COOR END

CLOSE langtest1.dat END

DYNAMICS ANALYSIS AVERAGE
           input=langtest1.dat  BEGIN=5 STOP=2500 SKIP=5
         END

vector show element ( b ) ( ALL )

close langtest1.dat end
open langtest1.dat access=append end    close langtest1.dat disp=delete end

STOP