remarks file xtalmr/rigid.inp -- Combine molecules and then
remarks                          do rigid-body refinement

{===>} structure @fab2hfl.psf end                    {*Read structure file.*}

{===>} coor @translation1.pdb   {Read coords from 1st translation function.*}


              {*In order to generate the 2nd molecule, we renumber the 1st.*}
vector do ( resid=encode(decode(resid)+1000)) ( all )


{===>} structure @fab2hfl.psf end{*Read structure file for second molecule.*}

{===>} coor @translation2.pdb  {*Read coords from 2nd translation function.*}

evaluate ($wa=10000.)                {* Use this weight if the only active *}
                                     {* energy term is XREF, otherwise, use*}
                                     {* the weight obtained from the       *}
                                     {* "check.inp" protocol.              *}

xrefin
{===>}                                             {*Unit cell for crystal.*}
   a=44.144 b=164.69 c=70.17 alpha=90. beta=108.50 gamma=90.

{===>}
   symmetry=(x,y,z)                 {*Operators for crystal symmetry P2(1).*}
   symmetry=(-x,y+1/2,-z) 


   SCATter ( chemical C* ) 
      2.31000 20.8439 1.02000 10.2075 1.58860 .568700 .865000 51.6512 .215600
   SCATter ( chemical N* )
      12.2126 .005700 3.13220 9.89330 2.01250 28.9975 1.16630 .582600 -11.529
   SCATter ( chemical O* )
      3.04850 13.2771 2.28680 5.70110 1.54630 .323900 .867000 32.9089 .250800
   SCATter ( chemical S* )
      6.90530 1.46790 5.20340 22.2151 1.43790 .253600 1.58630 56.1720 .866900
   SCATter ( chemical P* )
      6.43450 1.90670 4.17910 27.1570 1.78000 0.52600 1.49080 68.1645 1.11490
   SCATter ( chemical FE* )
      11.1764 4.61470 7.38630 0.30050 3.39480 11.6729 0.07240 38.5566 0.97070

{===>} 
   nreflections=30000 
   reflection @3r9a_det.fob end                         {*Read reflections.*}

{===>}   
   resolution 6.0 3.0                                   {*Resolution range.*}

   reduce   
   do amplitude ( fobs = fobs * heavy(fobs - 2.0*sigma))    {*Sigma cutoff.*}
   fwind=0.1=100000
      

{===>}    
   method=fft       
   fft 
       memory=2000000                   {*FFT method with memory statement.*}
   end

   wa=$wa 

   tolerance=0. lookup=false              {*This makes the minimizer happy.*}

end


  {*Translate the second molecule according to combined translation search;*}
  {*do the translation in fractional coordinates.                          *}
coor fractionalize end

 {*First apply the x, z translation that was used in job translation12.inp.*}
{===>} coor translate vector=( 0. 0. 0. ) selection=( resid 1:999 ) end

        {*Now apply the translation that was determined by the search in z.*}
{===>} coor translate vector=( 0.  0.957 0. ) selection=( resid 1:999 ) end

coor orthogonalize end


flags exclude * include xref end               {*Use only XREF energy term.*}


         {*Do rigid-body minimization of the orientation of both molecules.*}
minimize rigid 
   translation=false  {* Translation of the last group is kept fixed. *}                                 
   group=( resid 1:999 )        
   group=( resid 1000:1999 )
   nstep=20 drop=40. 
end
                    {*Do rigid-body minimization of the individual domains.*}
mini rigid
        translation=false  {* Translation of the last group is kept fixed. *}                                 
        group=( resid 1:106 and segid L ) 
        group=( resid 107:212 and segid L )   
        group=( resid 1:116 and segid H ) 
        group=( resid 117:213 and segid H ) 
        group=( resid 1000:1106 and segid L ) 
        group=( resid 1107:1212 and segid L )   
        group=( resid 1001:1116 and segid H ) 
        group=( resid 1117:1213 and segid H ) 
        drop=40.0
        nstep=50 
end               

xrefin
   update
   print r
end

write coor output=rigid.pdb end               {*Write combined coordinates.*}
write structure output=rigid.psf end       {*Write combined structure file.*}

stop