remarks  file  xtalrefine/bgroup.inp 
 remarks  Grouped, unrestrained B-factor refinement
               
{===>} parameter @TOPPAR:parhcsdx.pro end                {*Read parameters.*}

{===>} structure @../generate/generate.psf end       {*Read structure file.*}

{===>} coor @slowcool.pdb                               {*Read coordinates.*}
                                             

 xrefine                                    {*This invokes the             *}
                                            {*crystallographic data parser.*} 
{===>}
   a=61.76 b=40.73 c=26.74 alpha=90.0 beta=90.0 gamma=90.0     {*Unit cell.*}

{===>}
   symmetry=(x,y,z)                         {*Symmetry operators for space *}
   symmetry=(-x+1/2,-y,z+1/2)               {*group P212121; notation as in*}
   symmetry=(-x,y+1/2,-z+1/2)               {*Int. Tables.                 *}
   symmetry=(x+1/2,-y+1/2,-z) 
     
   SCATter ( chemical C* ) 
      2.31000 20.8439 1.02000 10.2075 1.58860 .568700 .865000 51.6512 .215600
   SCATter ( chemical N* )
      12.2126 .005700 3.13220 9.89330 2.01250 28.9975 1.16630 .582600 -11.529
   SCATter ( chemical O* )
      3.04850 13.2771 2.28680 5.70110 1.54630 .323900 .867000 32.9089 .250800
   SCATter ( chemical S* )
      6.90530 1.46790 5.20340 22.2151 1.43790 .253600 1.58630 56.1720 .866900
   SCATter ( chemical P* )
      6.43450 1.90670 4.17910 27.1570 1.78000 0.52600 1.49080 68.1645 1.11490
   SCATter ( chemical FE* )
      11.1764 4.61470 7.38630 0.30050 3.39480 11.6729 0.07240 38.5566 0.97070
 
{===>} 
   nreflections=15000
   reflection @amy.fob end                              {*Read reflections.*}

{===>}   
   resolution  5.0 2.0                                  {*Resolution range.*}

   reduce   
   do amplitude ( fobs = fobs * step(fobs - 2.0*sigma))     {*Sigma cutoff.*}
   fwind=0.1=100000

   method=FFT          
   
   fft 
      memory=1000000   
   end                 
      

   tolerance=0.0 lookup=false             {*This makes the minimizer happy.*}

 end                  

 xrefin                 
   optimize group

      {*The following loop selects two B-factor groups for each residue,   *}
      {*one for backbone (ca, n, c) and one for side-chain atoms.          *}
      {*The program knows that it has to go through all residues, since the*}
      {*loop goes over all ca atoms.                                       *}
      {*In principle, you can select any arbitrary group of B-factors here.*} 

      for $1 in id ( name ca ) loop main
        b=(( name ca or name n or name c ) and byres id $1 )
        b=( not ( hydro or name ca or name c or name n ) and
            byres id $1 )
      end loop main            

      nstep=15                                   {*Fifteen steps should be *}
      drop=1.0                                  {*sufficient in most cases.*}
      ? 
   end
 end


 write coordinates output=bgroup.pdb end           {*Write coordinates with*}
                                                   {*B-factors.            *} 
 stop