remarks  file  xtalrefine/check.inp 
 remarks  Check initial R value,
 remarks  compute ideal weights for diffraction energy terms

{===>} parameter @TOPPAR:parhcsdx.pro end                {*Read parameters.*}

{===>} structure @../generate/generate.psf end       {*Read structure file.*}

{===>} coor @../generate/generate.pdb                   {*Read coordinates.*}

{===>}                                     {*If the temperature factors and*}
 vector do (b=15.0) ( all )                {*occupancies are not defined in*}
 vector do (q=1.0) ( all )                 {*the coordinate file,          *}
                                           {*set them now.                 *}
 
 vector do ( charge=0.0 ) ( resname LYS and 
    ( name ce or name nz or name hz* ) )         {*Turn off charges on LYS.*}
 vector do ( charge=0.0 ) ( resname GLU and
    ( name cg or name cd or name oe* ) )         {*Turn off charges on GLU.*}
 vector do ( charge=0.0 ) ( resname ASP and
    ( name cb or name cg or name od* ) )         {*Turn off charges on ASP.*}
 vector do ( charge=0.0 ) ( resname ARG and
    ( name cd or name *E or name cz or name NH* or name HH* ) )
                                                 {*Turn off charges on ARG.*}

 flags                                     {*In addition to the empirical  *}
    include pele pvdw xref                 {*potential energy terms, which *}
    ?                                      {*are turned on initially,  this*}
 end                                       {*statement turns on the        *}
                                           {*crystallographic residual term*}
                                           {*and packing term.             *}

 xrefine                                    {*This invokes the             *}
                                            {*crystallographic data parser.*} 
{===>}
   a=61.76 b=40.73 c=26.74 alpha=90.0 beta=90.0 gamma=90.0     {*Unit cell.*}

{===>}
   symmetry=(x,y,z)                         {*Symmetry operators for space *}
   symmetry=(-x+1/2,-y,z+1/2)               {*group P212121; notation as in*}
   symmetry=(-x,y+1/2,-z+1/2)               {*Int. Tables.                 *}
   symmetry=(x+1/2,-y+1/2,-z)      
            {*The following contains the atomic form factors.  A 4-Gaussian*}
            {*approximation is used.  Atoms are selected based on their    *}
            {*chemical type.  Note the use of wildcards in the selection.  *} 

   SCATter ( chemical C* ) 
      2.31000 20.8439 1.02000 10.2075 1.58860 .568700 .865000 51.6512 .215600
   SCATter ( chemical N* )
      12.2126 .005700 3.13220 9.89330 2.01250 28.9975 1.16630 .582600 -11.529
   SCATter ( chemical O* )
      3.04850 13.2771 2.28680 5.70110 1.54630 .323900 .867000 32.9089 .250800
   SCATter ( chemical S* )
      6.90530 1.46790 5.20340 22.2151 1.43790 .253600 1.58630 56.1720 .866900
   SCATter ( chemical P* )
      6.43450 1.90670 4.17910 27.1570 1.78000 0.52600 1.49080 68.1645 1.11490
   SCATter ( chemical FE* )
      11.1764 4.61470 7.38630 0.30050 3.39480 11.6729 0.07240 38.5566 0.97070
 
{===>} 
   nreflections=15000
   reflection @amy.fob end                              {*Read reflections.*}

{===>}   
   resolution  5.0 2.0                                  {*Resolution range.*}

   reduce   
   do amplitude ( fobs = fobs * step(fobs - 2.0*sigma))     {*Sigma cutoff.*}
   fwind=0.1=100000

   print completeness                         {*Check completeness of data.*}

   method=FFT             {*Use the FFT method instead of direct summation.*}
   
   fft 
      memory=1000000  {*This tells the FFT routine how much physical memory*}
   end                {*is available; the number refers to DOUBLE COMPLEX  *}
                      {*words, the memory is allocated from the HEAP.      *}
      

   ?                                      {*This prints the current status.*}

 end                         {*This terminates the diffraction data parser.*}
                                      
 xrefin                                       {*This statement computes the*}
                                              {*initial R value.           *} 
                                                {*Please check the R value.*}
   update-fcalc                             {*This is the last check before*}
   print R                                  {*wasting a lot of computer    *}
 end                                        {*time.                        *}

 flags                                        {*TURN OFF diffraction terms *}
   exclude xref                               {*but KEEP packing term and  *}
 end                                          {*empirical potential energy.*}
 
 minimize powell                             {*Invoke the Powell minimizer.*}

   nstep=40                                                 {*Do 40 cycles.*}

   drop=40.0                                 {*This is the expected initial*}
                                             {*drop in energy; the value is*}
                                             {*not critical: 40.0 should be*}
                                             {*reasonable in most cases.   *}

 end                                            {*Minimization is executed.*}

 dynamics  verlet                              {*Invoke Verlet integration.*}
 
   timestep=0.001                               {*Time step in picoseconds.*}
   nstep=100                                 {*Number of integration steps.*}

   iasvel=maxwell                          {*Initial velocities from       *}
   firsttemperature=300                    {*Maxwell distribution at 300 K.*}

   ieqfrq=25                                   {*Scale the velocities every*}
   finaltemperature=300                        {*25 steps.                 *}

   nprint=50 iprfrq=100                                   {*Output control.*}
   nsavc=0                                {*Do not write a trajectory file.*}

 end                                        {*Integration will be executed.*}

                                            {*Now compute the ideal weight *}
                                            {*at the specified resolution  *}
                                            {*range by comparing gradients.*}
 energy end
 evaluate ($grad_ener=$grad)
 xrefin
   wa=1. wp=0.       
   resolution 5. 2. 
 end
 flags exclude * include xref end
 energy end
              {* Experience has shown that the gradient ratio has to be    *}
              {* divided by a factor of two to three for optimum Rfree and *}
              {* maximum phase accuracy.                                   *}
 evaluate ($weight= $grad_ener/(2.* $grad))

 display  suggested weight wa = $weight

             {*To determine the ideal weight for the phase-dependent term,*}
             {*uncomment the following lines.                             *}
! xrefin
!   wa=0. wp=1.       
!   resolution 5. 2. 
! end
! energy end
!             {* Experience has shown that the gradient ratio has to be    *}
!              {* divided by a factor of two to three for optimum Rfree and *}
!              {* maximum phase accuracy.                                   *}
!evaluate ($weight= $grad_ener/(2.* $grad))
!
! display  suggested weight wp = $weight

 stop