remarks  file  xtalrefine/rigid.inp 
 remarks  Rigid-body refinement against the XREF term
               
{===>} structure @../generate/generate.psf end       {*Read structure file.*}

{===>} coor @prepstage.pdb                              {*Read coordinates.*}
                                             
 flags                                       
    exclude * include  xref   {* In this example we use the XREF term only.*}          
    ?                                        
 end                                         
                                            

 xrefine 
                                  
{===>}
   a=61.76 b=40.73 c=26.74 alpha=90.0 beta=90.0 gamma=90.0     {*Unit cell.*}

{===>}
   symmetry=(x,y,z)                         {*Symmetry operators for space *}
   symmetry=(-x+1/2,-y,z+1/2)               {*group P212121; notation as in*}
   symmetry=(-x,y+1/2,-z+1/2)               {*Int. Tables.                 *}
   symmetry=(x+1/2,-y+1/2,-z)      

   SCATter ( chemical C* ) 
      2.31000 20.8439 1.02000 10.2075 1.58860 .568700 .865000 51.6512 .215600
   SCATter ( chemical N* )
      12.2126 .005700 3.13220 9.89330 2.01250 28.9975 1.16630 .582600 -11.529
   SCATter ( chemical O* )
      3.04850 13.2771 2.28680 5.70110 1.54630 .323900 .867000 32.9089 .250800
   SCATter ( chemical S* )
      6.90530 1.46790 5.20340 22.2151 1.43790 .253600 1.58630 56.1720 .866900
   SCATter ( chemical P* )
      6.43450 1.90670 4.17910 27.1570 1.78000 0.52600 1.49080 68.1645 1.11490
   SCATter ( chemical FE* )
      11.1764 4.61470 7.38630 0.30050 3.39480 11.6729 0.07240 38.5566 0.97070
 
{===>} 
   nreflections=15000
   reflection @amy.fob end                              {*Read reflections.*}

{===>}   
   resolution  5.0 2.0                                  {*Resolution range.*}

   reduce   
   do amplitude ( fobs = fobs * heavy(fobs - 2.0*sigma))    {*Sigma cutoff.*}
   fwind=0.1=100000

   method=FFT          
   
   fft 
      memory=1000000   
   end                 
      

   tolerance=0.0 lookup=false        {* These options are required for the *}
                                     {* minimizer.*}

   wa=10000                          {* Use this weight if the only active *}
                                     {* energy term is XREF, otherwise, use*}
                                     {* the weight obtained from the       *}
                                     {* "check.inp" protocol.              *}
 end                  


 minimize rigid                               

      nstep=40                                      {*Do 40-step rigid-body*}
                                                    {*minimization.        *}

      drop=10.0                          {*Expected initial drop in energy.*}

      group=( resid 1:30 )                       {*Select two rigid groups.*}
      group=( resid 31:70 )                      

 end                                         

 write coordinates output=rigid.pdb end          {*Write final coordinates.*}

 stop