remarks  file xtalrefine/solscale.inp 
 remarks  Determine scale factor and b-factor for solvent
 remarks  Fs by trial and error
 
{===>} parameter @TOPPAR:parhcsdx.pro end                {*Read parameters.*}

{===>} structure @../generate/generate.psf end       {*Read structure file.*}

{===>} coor @slowcool.pdb                               {*Read coordinates.*}
                                             

 xrefine                                    {*This invokes the             *}
                                            {*crystallographic data parser.*} 
{===>}
   a=61.76 b=40.73 c=26.74 alpha=90.0 beta=90.0 gamma=90.0     {*Unit cell.*}

{===>}
   symmetry=(x,y,z)                         {*Symmetry operators for space *}
   symmetry=(-x+1/2,-y,z+1/2)               {*group P212121; notation as in*}
   symmetry=(-x,y+1/2,-z+1/2)               {*Int. Tables.                 *}
   symmetry=(x+1/2,-y+1/2,-z)      

   SCATter ( chemical C* ) 
      2.31000 20.8439 1.02000 10.2075 1.58860 .568700 .865000 51.6512 .215600
   SCATter ( chemical N* )
      12.2126 .005700 3.13220 9.89330 2.01250 28.9975 1.16630 .582600 -11.529
   SCATter ( chemical O* )
      3.04850 13.2771 2.28680 5.70110 1.54630 .323900 .867000 32.9089 .250800
   SCATter ( chemical S* )
      6.90530 1.46790 5.20340 22.2151 1.43790 .253600 1.58630 56.1720 .866900
   SCATter ( chemical P* )
      6.43450 1.90670 4.17910 27.1570 1.78000 0.52600 1.49080 68.1645 1.11490
   SCATter ( chemical FE* )
      11.1764 4.61470 7.38630 0.30050 3.39480 11.6729 0.07240 38.5566 0.97070
 
{===>} 
   nreflections=15000
   reflection @amy_s.fob end      {*Read reflections, including solvent Fs.*}

{===>}   
   resolution  40. 2.0        {*Resolution range, including low-resolution.*}

   reduce   
   do amplitude ( fobs = fobs * step(fobs - 2.0*sigma))   {*Sigma cut off.*}
   fwind=0.1=100000

   method=FFT          
   
   fft 
      memory=1000000   
   end                 
      
 end                  

xrefine
   update                                                 {*Compute Fcalcs.*}

   mbins 45                          {*Number of bins for rfactor printout.*}

                        {*First loop keeps the B-factor fixed and varies k.*}
{===>}
   evaluate ($bfactor=100.)              {*Apply B of 200 when modifying k.*}

   do (FPART=( FPART*exp(-$bfactor*(s()^2)/4.) ))  
                                                 
                                          {*Determine scale factor k*FPART.*}
   evaluate ($1 = 0.390) {*Loop over k, starting at 0.39 and ending at 0.1.*}
   evaluate ($2 = 1.0)
   while ($1 > .100 ) loop solk
      evaluate ( $1 = $1 - .02 )
      do ( FPART = ($1/$2)*FPART)
      print rfactor   
      evaluate ($2 = $1)
   end loop solk

   do ( FPART = (exp($bfactor*(s()^2)/4.) / $2)*FPART ) 
                                                 {*Retrieve original FPART.*}

                    {*Second loop keeps k constant and varies the B-factor.*}

{===>}
   evaluate ($kpart=0.31)  {*Apply a k of 0.27 when modifying the B-factor.*}

   do (FPART =  FPART*$kpart )  

   evaluate ($1 = 200.)
   evaluate ($2 = 0.)
   while ($1 > 0. ) loop bfac
      evaluate ( $1 = $1 - 25.)
      do (FPART=( FPART*exp(-($1 - $2)*(s()^2)/4.) )) 
      print rfactor   
      evaluate ($2 = $1)
   end loop bfac

   do ( FPART = (exp($2*(s()^2)/4.) / $kpart)*FPART ) 
                                                 {*Retrieve original FPART.*}

                          {*Do a test with the current $kpart and $bfactor.*}
   do ( FPART= $kpart * exp(-$bfactor*(s()^2)/4.)*FPART ) 
   print rfactor
end

          {*Modify $kpart and $bfactor and rerun this job until the results*}
          {*are optimal when modifying either k or b.                      *}              

stop