remarks file xtalrefine/wilson.inp
remarks  Wilson plot.  If no molecular structure present see note at the 
remarks  bottom

                                           {*Read structure file.          *}
{===>} structure @../generate/generate.psf end    

{===>} coordinates @slowcool.pdb           {* Read coordinates.            *}
                        {* Note: the Wilson plot is independent of atomic  *}
                        {* positions, but X-PLOR produces warning messages *}
                        {* if atomic coordinates are unknown.  Just read   *}
                        {* any coordinate set or define fake coordinates.  *}




set print=wilson.list end

xrefine

{===>}                                  
   a=61.76 b=40.73 c=26.74 alpha=90.0 beta=90.0 gamma=90.0     {*Unit cell.*}

{===>}
   symmetry=(x,y,z)                       {*Symmetry operators for space   *}
   symmetry=(-x+1/2,-y,z+1/2)             {*group P212121 notation as in   *}
   symmetry=(-x,y+1/2,-z+1/2)             {*Int. Tables.                   *}
   symmetry=(x+1/2,-y+1/2,-z)      

   SCATter ( chemical C* ) 
      2.31000 20.8439 1.02000 10.2075 1.58860 .568700 .865000 51.6512 .215600
   SCATter ( chemical N* )
      12.2126 .005700 3.13220 9.89330 2.01250 28.9975 1.16630 .582600 -11.529
   SCATter ( chemical O* )
      3.04850 13.2771 2.28680 5.70110 1.54630 .323900 .867000 32.9089 .250800
   SCATter ( chemical S* )
      6.90530 1.46790 5.20340 22.2151 1.43790 .253600 1.58630 56.1720 .866900
   SCATter ( chemical P* )
      6.43450 1.90670 4.17910 27.1570 1.78000 0.52600 1.49080 68.1645 1.11490
   SCATter ( chemical FE* )
      11.1764 4.61470 7.38630 0.30050 3.39480 11.6729 0.07240 38.5566 0.97070

{===>} 
   nreflections=15000
   reflection @amy.fob end                              {*Read reflections.*}

   reduce   
   do amplitude ( fobs = fobs * step(fobs - 2.0*sigma))     {*Sigma cutoff.*}
   fwind=0.1=100000


   method=FFT        {*Use the FFT method instead of direct summation.     *}
   
   fft 
      memory=1000000 
   end 
             
   mbins=40

   resolution=10.0 2.

   print wilson
end


stop

           {* If no molecular structure is present, simply generate a fake *}
           {* structure with the appropriate number of point atoms. Use the*}
           {* following statements instead of the structure and coordinate *}
           {* statements.                                                  *}

!topology
!    residue C
!      atom=C type C mass=12.0 end
!    end
!    residue N
!      atom=N type N mass=14.0 end
!    end
!    residue O
!      atom=O type O mass=16.0 end
!    end
!    residue S
!      atom=S type S mass=32.0 end
!    end
!end
!
!segment                             {* Insert the actual number of atoms. *}
!    mole name=C number=345 end  
!    mole name=N number=93  end
!    mole name=O number=116  end
!    mole name=S number=4   end
!end
!
!vector do (x=1.) ( all )                     {* Generate fake coordinates *}
!vector do (y=1.) ( all )                     {* to avoid error messages   *}
!vector do (z=1.) ( all )                     {* about unknown atoms.      *}